---
title: Отправить письмо на почту
slug: примеры-сниппеты-бсп-и-типовые-работа-с-почтой/отправить-письмо-на-почту
---
```bsl

Процедура ОтправитьПисьмо(АдресЭлектроннойПочты, ТекстСообщения, ТемаСообщения) Экспорт
	
	Если Не ОбщегоНазначенияКлиентСервер.АдресЭлектроннойПочтыСоответствуетТребованиям(АдресЭлектроннойПочты, Ложь) Тогда
		ЗаписьЖурналаРегистрации("Рассылка уведомлений на электронную почту", 
			УровеньЖурналаРегистрации.Ошибка,,,
			СтрШаблон("Ошибка отправки сообщения. Адрес ""%1"" не валиден", АдресЭлектроннойПочты));
		Возврат;
	КонецЕсли;
	
	УчетнаяЗапись = РаботаСПочтовымиСообщениями.СистемнаяУчетнаяЗапись();
	
	ПараметрыПисьма = Новый Структура;
	ПараметрыПисьма.Вставить("Кому", АдресЭлектроннойПочты);
	ПараметрыПисьма.Вставить("Тема", ТемаСообщения);
	ПараметрыПисьма.Вставить("Тело", ТекстСообщения);
	
	Письмо = РаботаСПочтовымиСообщениями.ПодготовитьПисьмо(УчетнаяЗапись, ПараметрыПисьма);
	
	Попытка
		РаботаСПочтовымиСообщениями.ОтправитьПисьмо(УчетнаяЗапись, Письмо);
	Исключение
		ЗаписьЖурналаРегистрации("Рассылка уведомлений на электронную почту", 
			УровеньЖурналаРегистрации.Ошибка,,,
			СтрШаблон("Ошибка отправки сообщения. Описание ошибки %1", ПодробноеПредставлениеОшибки(ИнформацияОбОшибке())));
	КонецПопытки;
	
КонецПроцедуры
```