---
title: Обход всех строк динамического списка
slug: примеры-сниппеты-общее-динамические-списки/обход-всех-строк-динамического-списка
---

```bsl
&НаСервере
Функция ДанныеВсехСтрокДинамическогоСпискаПулНоменклатурыРазмещение()
	
	//Получаем схема компановки данных (здесь хранится текст запроса)
	Схема = Элементы.ПулНоменклатурыРазмещение.ПолучитьИсполняемуюСхемуКомпоновкиДанных();
	
	//Получаем настройки пользователя (отборы, сортировки и т.п.)
	Настройки = Элементы.ПулНоменклатурыРазмещение.ПолучитьИсполняемыеНастройкиКомпоновкиДанных();
	
	//Выводим динамический список в таблицу значений
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных();
	МакетКомпоновки = КомпоновщикМакета.Выполнить(Схема, Настройки, , ,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	Результат = ПроцессорВывода.Вывести(ПроцессорКомпоновки); //  Тут таблица значений со строками ДС
	
	ДанныеСтрок = Новый Массив;
	
	Для Каждого Строка Из Результат Цикл // Обходим ТЗ
		
		ДанныеСтроки = ПараметрыЗаполненияСтрокиТабличнойЧастиРазмещение();
		ЗаполнитьЗначенияСвойств(ДанныеСтроки, Строка);
		ДанныеСтроки.Количество = Строка.Разместить;
		
		ДанныеСтрок.Добавить(ДанныеСтроки);
		
	КонецЦикла;
	
	Возврат ДанныеСтрок;
	
КонецФункции
```