---
title: Добавить файл
slug: общие-бсп-стандартные-подсистемы-3-1-10-файлы-программный-интерфейс-клиент/добавить-файл
---

# Описание

```bsl
// Открывает диалог выбора файлов для помещения в программу одного выбранного файла.
// Синтаксис
//
// Процедура ДобавитьФайл(ОбработчикРезультата, ВладелецФайла, ФормаВладелец, РежимСоздания = Неопределено, 
//	ПараметрыДобавления = Неопределено) Экспорт
// Параметры
//
//   ОбработчикРезультата - ОписаниеОповещения - содержит описание процедуры, вызов которой будет произведен
//                        после добавления файла со следующими параметрами:
//                    * Результат - Структура:
//                       ** ФайлСсылка - ОпределяемыйТип.ПрисоединенныйФайл - ссылка на элемент справочника с файлом,
//                                     если он был добавлен, иначе Неопределено.
//                       ** ФайлДобавлен - Булево - Истина, если файл добавлен.
//                       ** ТекстОшибки  - Строка - текст ошибки, если файл не был добавлен.
//                    * ДополнительныеПараметры - Произвольный - значение, указанное при создании объекта оповещения.
//   ВладелецФайла - ОпределяемыйТип.ВладелецПрисоединенныхФайлов - папка файлов или объект, к которому
//                 требуется прикрепить добавляемый файл.
//   ФормаВладелец - ФормаКлиентскогоПриложения - форма, из которой вызвано создание файла.
//   РежимСоздания - Неопределено
//                 - Число - режим создания файла:
//                 - Неопределено - показать диалог выбора режима создания файла.
//                 - Число - создать файл указанным способом:
//                           1 - из шаблона (копированием другого файла);
//                           2 - с компьютера (из файловой системы);
//                           3 - со сканера.
//   ПараметрыДобавления - Структура - дополнительные параметры добавления файлов:
//     * МаксимальныйРазмер  - Число - ограничение на размер файла (в мегабайтах), загружаемого из файловой системы.
//                           Если принимает значение 0, проверка размера не проводится. Свойство игнорируется,
//                           если принимает значение больше, чем указано в константе МаксимальныйРазмерФайла.
//     * ФильтрДиалогаВыбора - Строка - фильтр, устанавливаемый в диалог выбора при добавлении файла.
//                           Формат см. в свойстве Фильтр объекта ДиалогВыбораФайла в синтакс-помощнике.
//     * НеОткрыватьКарточку - Булево - действие после создания. Если принимает значение Истина, карточка файла
//                           не будет открыта после создания, иначе - карточку файла будет открыта.
РаботаСФайламиКлиент.ДобавитьФайл(Оповещение, Ссылка, ЭтотОбъект, РежимСоздания);
```

# Пример применения
```bsl
&НаКлиенте
Процедура ДобавитьФайл(Команда)
	
	// Режимы создания:
	// 1 - из шаблона (копированием другого файла)
	// 2 - с компьютера (из файловой системы)
	// 3 - со сканера

	РежимСоздания = 2; 
	
	Оповещение = Новый ОписаниеОповещения("ДобавитьФайлЗавершение", ЭтотОбъект);
	РаботаСФайламиКлиент.ДобавитьФайл(Оповещение, Объект.Номенклатура, ЭтотОбъект, РежимСоздания);
	
КонецПроцедуры

&НаКлиенте
Процедура ДобавитьФайлЗавершение(Результат, ДополнительныеПараметры) Экспорт
	
	Если Результат = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	Если НЕ Результат.ФайлДобавлен Тогда
		ОбщегоНазначенияКлиент.СообщитьПользователю(Результат.ТекстОшибки);		
		Возврат;
	КонецЕсли;   

	ОбщегоНазначенияКлиент.СообщитьПользователю("Файл добавлен: " + Результат.ФайлСсылка);

КонецПроцедуры // ДобавитьФайлЗавершение()

```