---
title: Значения свойств
slug: общие-бсп-стандартные-подсистемы-3-1-10-свойства-программный-интерфейс/значения-свойств
---

# Описание

```bsl
// Возвращает значения дополнительных свойств объектов.
// Синтаксис
//
// Функция ЗначенияСвойств(ОбъектыСоСвойствами,
//                        ПолучатьДопРеквизиты = Истина,
//                        ПолучатьДопСведения = Истина,
//                        Свойства = Неопределено,
//                        КодЯзыка = "") Экспорт
// Параметры
//
//  ОбъектыСоСвойствами  - Массив      - объекты, для которых нужно получить значения дополнительных свойств.
//                       - ЛюбаяСсылка - ссылка на объект, например, СправочникСсылка.Номенклатура,
//                                       ДокументСсылка.ЗаказПокупателя, ...
//  ПолучатьДопРеквизиты - Булево - в результат включать дополнительные реквизиты. По умолчанию Истина.
//  ПолучатьДопСведения  - Булево - в результат включать дополнительные сведения. По умолчанию Истина.
//  Свойства             - Массив из ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения - значения
//                            которых следует получить.
//                       - Массив из Строка - уникальное имя дополнительного свойства. 
//                       - Неопределено - по умолчанию, получить значения всех свойств владельца.
//  КодЯзыка             - Строка - код языка, на котором будет получено представление значения свойства.
//                                  Если не указано - берется текущий язык.
// Возвращаемое значение
//
//  ТаблицаЗначений:
//    * Свойство    - ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения - свойство владельца.
//    * ИмяСвойства - Строка - уникальное имя свойства владельца.
//    * Значение    - Произвольный - значения любого типа из описания типов свойства объекта метаданных:
//                    "Метаданные.ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения.Тип".
//    * Представление   - Строка - представление значения на указанном языке.
//    * ВладелецСвойств - ЛюбаяСсылка - ссылка на объект.
ТаблицаСвойств = УправлениеСвойствами.ЗначенияСвойств(ОбъектыСоСвойствами);
```

# Пример применения
```bsl
// 1. Получение значений свойств одного объекта
Номенклатура = Справочники.Номенклатура.НайтиПоКоду("000000001");
Если НЕ Номенклатура.Пустая() Тогда

	ТаблицаСвойств = УправлениеСвойствами.ЗначенияСвойств(Номенклатура);
	ТаблицаСвойств.ВыбратьСтроку();
	
Иначе
	ОбщегоНазначения.СообщитьПользователю("Номенклатура не найдена");	
КонецЕсли;

// 2. Получение значений свойств нескольких объектов
Группа = Справочники.Номенклатура.НайтиПоКоду("000000001");

Если НЕ Группа.Пустая() Тогда

	МассивТоваров = Новый Массив;
	Выборка = Справочники.Номенклатура.Выбрать(Группа);
	Пока Выборка.Следующий() Цикл
		Если НЕ Выборка.ЭтоГруппа Тогда
			МассивТоваров.Добавить(Выборка.Ссылка);
		КонецЕсли;
	КонецЦикла;
	
	ТаблицаСвойств = УправлениеСвойствами.ЗначенияСвойств(МассивТоваров);
	ТаблицаСвойств.ВыбратьСтроку();
	
Иначе
	ОбщегоНазначения.СообщитьПользователю("Номенклатура не найдена");	
КонецЕсли;
```