---
title: Добавить присоединенный файл (сервер)
slug: общие-работа-с-присоединенными-файлами/добавить-присоединенный-файл-сервер
---

# Описание

```bsl
// Создает объект в справочнике для хранения файла и заполняет его реквизиты переданными свойствами.
// Синтаксис
//
// Функция ДобавитьФайл(ПараметрыФайла,
//                     Знач АдресФайлаВоВременномХранилище,
//                     Знач АдресВременногоХранилищаТекста = "",
//                     Знач Описание = "",
//                     Знач НоваяСсылкаНаФайл = Неопределено) Экспорт
// Параметры
//
//   ПараметрыФайла                 - см. РаботаСФайлами.ПараметрыДобавленияФайла.
//   АдресФайлаВоВременномХранилище - Строка - адрес, указывающий на двоичные данные во временном хранилище.
//   АдресВременногоХранилищаТекста - Строка - адрес, указывающий на извлеченный текст из файла во временном хранилище.
//   Описание                       - Строка - текстовое описание файла.
//   НоваяСсылкаНаФайл              - Неопределено - если у владельца файла только один справочник хранения файлов.
//                                  - ОпределяемыйТип.ПрисоединенныйФайл - ссылка на элемент справочника хранения файлов,
//                                    которую следует использовать для добавляемого файла.
//                                    Должна соответствовать одному из типов справочников хранения файлов владельца
//                                    файлов. Ссылка может быть получена функцией НоваяСсылкаНаФайл.
// Возвращаемое значение
//
//   ОпределяемыйТип.ПрисоединенныйФайл - ссылка на созданный присоединенный файл.
ФайлСсылка = РаботаСФайлами.ДобавитьФайл(ПараметрыДобавления, АдресФайла);
```

# Пример применения
```bsl
НоменклатураСсылка = Справочники.Номенклатура.НайтиПоКоду("00000000016");

Если НЕ НоменклатураСсылка.Пустая() Тогда

	ПутьКФайлу = "C:\temp\Картинки для сайта\site_image.png";
	ДанныеФайла = Новый ДвоичныеДанные(ПутьКФайлу);	
	АдресФайла = ПоместитьВоВременноеХранилище(ДанныеФайла);	
	
	ПараметрыДобавления = РаботаСФайлами.ПараметрыДобавленияФайла();
	ПараметрыДобавления.Автор = Пользователи.ТекущийПользователь();
	ПараметрыДобавления.ВладелецФайлов = НоменклатураСсылка;
	ПараметрыДобавления.ИмяБезРасширения = "site_image";
	ПараметрыДобавления.РасширениеБезТочки = "png";

	ФайлСсылка = РаботаСФайлами.ДобавитьФайл(ПараметрыДобавления, АдресФайла);
	
	ОбщегоНазначения.СообщитьПользователю("К номенклатуре успешно присоединен файл картинки: " + ФайлСсылка);
	
Иначе
	ОбщегоНазначения.СообщитьПользователю("Номенклатура не найдена");
КонецЕсли;
```