---
title: Как выгрузить изменения в сообщение обмена
slug: общие-обмен-данными-1-планы-обмена/как-выгрузить-изменения-в-сообщение-обмена
---
```bsl
УзелОбмена = ПланыОбмена.ОбменИсточникПриемник.НайтиПоКоду("ПР");

Если НЕ УзелОбмена.Пустая() Тогда

    // 0. Создаем объект ЗаписьXML для формирования XML-файла
    ПутьКФайлуСообщения = "S:\Exchange\Message_ИС_ПР.xml";
    ЗаписьXML = Новый ЗаписьXML();
    ЗаписьXML.ОткрытьФайл(ПутьКФайлуСообщения);

    // 1. Создаем объект "ЗаписьСообщенияОбмена"
    ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
    
    // 2. Начинаем запись сообщения обмена для выбранного узла в файл XML
    ЗаписьСообщения.НачатьЗапись(ЗаписьXML, УзелОбмена);
    
    // 3. Выбираем изменения
    ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(УзелОбмена, ЗаписьСообщения.НомерСообщения);	
    
    // 4. Записываем изменения в файл XML
    Пока ВыборкаИзменений.Следующий() Цикл
        Данные = ВыборкаИзменений.Получить();
        ЗаписатьXML(ЗаписьXML, Данные);
    КонецЦикла;
    
    // 5. Заканчиваем запись сообщения обмена
    ЗаписьСообщения.ЗакончитьЗапись();
    
    Сообщение = Новый СообщениеПользователю;
    Сообщение.Текст = "Сообщение обмена успешно сформировано!";
    Сообщение.Сообщить();
    
Иначе
    Сообщение = Новый СообщениеПользователю;
    Сообщение.Текст = "Не найден узел плана обмена";
    Сообщение.Сообщить();
КонецЕсли;
```