---
title: Параметры выбора программно
slug: общие-управляемые-формы/параметры-выбора-программно
---

```bsl

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	УстановитьПараметрВыбораПоляВидОбъекта();
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервере
Процедура УстановитьПараметрВыбораПоляВидОбъекта()

	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	УДК_ВидыОбъектовМетаданных.Ссылка КАК Ссылка
	|ИЗ
	|	Справочник.УДК_ВидыОбъектовМетаданных КАК УДК_ВидыОбъектовМетаданных
	|ГДЕ
	|	УДК_ВидыОбъектовМетаданных.Ссылка <> ЗНАЧЕНИЕ(Справочник.УДК_ВидыОбъектовМетаданных.Подсистема)
	|	И НЕ УДК_ВидыОбъектовМетаданных.ЭтоГруппа";
	
	МассивДопустимыхВидов = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Ссылка");
	ФиксированныйМассив = Новый ФиксированныйМассив(МассивДопустимыхВидов);
	
	НовыйПараметр = Новый ПараметрВыбора("Отбор.Ссылка", ФиксированныйМассив);
	
	МассивПараметров = Новый Массив;
	МассивПараметров.Добавить(НовыйПараметр);
	
	НовыеПараметры = Новый ФиксированныйМассив(МассивПараметров);
	
	Элементы.ВидОбъекта.ПараметрыВыбора = НовыеПараметры;
	
КонецПроцедуры

#КонецОбласти
```