---
title: Проверка заполнения документа
slug: общие-документы/проверка-заполнения-документа
---

```bsl
Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)
	
	НепроверяемыеРеквизиты = Новый Массив; // сюда имена реквизитов, которые нужно исключить из проверки
	
	Если Статус = Перечисления.УДК_СтатусыВыполненияЗаданий.ВРаботе Тогда
		НепроверяемыеРеквизиты.Добавить("Аналитик");
	КонецЕсли;
	
	Если Статус = Перечисления.УДК_СтатусыВыполненияЗаданий.Закрыта Тогда
        // в этот массив можно добавить реквизиты, которые нужно проверить
		ПроверяемыеРеквизиты.Добавить("СписокОбъектов.ДатаПомещения"); 
	КонецЕсли;
	
	ОбщегоНазначения.УдалитьНепроверяемыеРеквизитыИзМассива(ПроверяемыеРеквизиты, НепроверяемыеРеквизиты);
	
    // Тут проверяем каждую строку ТЧ и привязваем сообщение об ошибке к конкретной ячейки конкретной строки
	Для Каждого Строка Из СписокОбъектов Цикл
		
		Если Не ЗначениеЗаполнено(Строка.ДатаПомещения) И Строка.СостояниеОбъекта = Перечисления.УДК_СостоянияОбъектов.ПомещенВХранилище Тогда
			
			ОбщегоНазначения.СообщитьПользователю("Заполните дату помещения в ХК",
				,
				ОбщегоНазначенияКлиентСервер.ПутьКТабличнойЧасти("Объект.СписокОбъектов", Строка.НомерСтроки, "ДатаПомещения"),
				,
				Отказ)

		КонецЕсли;
		
	КонецЦикла;
	
КонецПроцедуры
```